[Main]
Title=PENetwork
Description=Network (LAN/WLAN) Settings and Support
Selected=True
Level=6
Author=MaineCoon
Version=059
Date=13.07.2025
Credits=Holger Kotsch (https://penetworkmanager.de/)
AppDir=%AppsDir%\PENetwork_MC\PENetwork_x64\
Sizex86=pScrollBox1-1|1048:1788251:852
Sizex64=pScrollBox1-1|1048:1975131:0

[Interface]
Panel=1
pFrame1=Initialization,707070,1:0,0,10,0,125,55
pFrame2=Program version,707070,1:0,0,140,0,125,55
pFrame3=Shortcuts + Download,707070,0,0,10,55,255,90
pFrame4=PENetwork Configuration,707070,0,0,270,55,278,90
pFrame6=Available Settings,707070,0,0,10,150,540,195
pFrame7=Paths to Profiles,707070,1,0,10,145,540,210
pFrame8=PENetwork Profile (INI file),707070,1:1,0,30,160,500,90
pFrame9=WLAN Profile (XML file),707070,1,0,30,250,500,90

pScrollBox1=Run from RAM,1,1:0,0,20,20,105,20,Run from RAM
pScrollBox2=5,1,1:0,0,225,231,45,20,5,10,15,20,25
pScrollBox3=Auto,1,0,0,430,117,110,20,Auto,Czech,English,French,German,Hungarian,Italian,Polish,Portuguese,Portuguese (BR),Russian,Spanish,Swedish,Turkish
pScrollBox4=Show main window,1,0,0,180,301,160,20,Show main window,Minimize program,Close program
pScrollBox5=Beta,1,1:0,0,160,20,70,20,Beta,v0.58.2

pCheckBox1=True,Start menu,0,22,30,75,90,20
pCheckBox2=True,Desktop,0,22,30,99,90,20
pCheckBox3=False,Download latest version automatically,0,0,30,123,230,18
pCheckBox4=True,Autostart with WinPE,0,0,30,215,190,18
pCheckBox5=True,Startup Countdown (sec),0,0,30,235,190,18
pCheckBox6=True,Set Startup prompt to uppermost window,0,0,30,255,250,18
pCheckBox7=True,Start 'FileSharing' after starting network,0,0,30,275,250,18
pCheckBox8=True,Drive sharing after file sharing,0,0,290,175,250,18
pCheckBox9=False,Small Tabs in PENetwork GUI,0,0,290,195,250,18
pCheckBox10=True,Scan for new devices at any startup,0,0,290,215,250,18
pCheckBox11=True,Show Connection Activity in Taskbar,0,0,290,235,250,18
pCheckBox12=True,Always install network services,0,0,290,255,250,18
pCheckBox13=True,Debug-Modus,0,0,290,275,140,18

pTextBox1=.,Start menu folder,0,0,135,80,120,20

pTextLabel1=Available Languages:,9,0,Default,290,120,137,20
pTextLabel2=After starting Network:,9,0,Default,30,305,150,20

pButton1=PE_License,PENetwork License,0,Button,275,10,100,30
pButton2=AutoIt3_License,AutoIt3 EULA,0,Button,380,10,90,30
pButton3=ReadMe,READ ME,0,Button,470,10,80,30
pButton4=Debug,Debug-Info,0,Button,430,274,91,20
pButton5=ProfileEditor,Profile Editor (english),1,Button,400,175,120,30
pButton6=InfoINI,INI Info,1,Button,320,185,70,20
pButton7=WLanEditor,WLAN Editor (englisch),1,Button,400,265,120,30
pButton8=InfoWLAN,WLAN Info,1,Button,320,275,70,20
pButton9=Open_INI,Open Folder,1,Button,400,215,100,20
pButton10=Open_WLAN,Open Folder,1,Button,400,305,100,20

pRadioButton1=True,Auto Configuration,0,1,290,73,200,20
pRadioButton2=False,Custom Settings,0,1,290,95,200,20
pRadioButton3=True,Startup Prompt,0,2,30,175,250,20
pRadioButton4=False,Auto IP Configuration,0,2,30,195,250,20

pFileBox1=%BaseDir%\Temp\PENetwork\INI\,PENet (*.ini),1,FileDir,50,215,300,20
pFileBox2=%BaseDir%\Temp\PENetwork\WLAN\,WLan (*.xml),1,FileDir,50,305,300,20
//----Echo
tEcho_3=Download of
tEcho_4=Copying system files...
tEcho_5=The WLAN Profile will be copied to 'Windows\System32'...
tEcho_6=Extracting Download...
tEcho_7=Writing [PENetwork.ini]...
tEcho_8=Writing Registry files...
tEcho_9=Running Editor...
tEcho_10=Profile selection is activated
//----Information
tMsg_1=Please choose a directory
tMsg_2=The WLAN configuration file (.xml file) has not been found.#$xIntegration in PENetwork is not possible.
tMsg_3=Only files with extension 'xml' can be integrated.#$xIntegration of this file is not possible.#$x#$xPlease check all your settings.
tMsg_4=No file defined.#$xThe script will use the settings for#$x#$x- 'Auto Configuration'
tMsg_5=The chosen file is not an INI file.#$xThe script will use the settings for#$x#$x- 'Auto Configuration'
tMsg_6=The chosen file does not contain any usable informations.#$xThe script will use the settings for#$x#$x- 'Auto Configuration'
tMsg_7=Could not find the chosen INI file.#$x#$xThe script will use the settings for#$x#$x- 'Auto Configuration'
tMsg_9=PENetwork Profile:
tMsg_10=WLAN Profile:
//----Error
tMsg_11=Error detecting language of source.#$x#$xTherefore PENetwork will use the language ENGLISH.

tLangList_Beta=|cs-CZ=0405|en-US=0409|fr-FR=040c|de-DE=0407|hu-HU=040e|it-IT=0410|pl-PL=0415|pt-PT=0816|pt-BR=0416|ru-RU=0419|es-ES=040a|sv-SE=041d|tr-TR=041f
tLangList_0582=|cs=0405|Eng=0409|Fr=040c|Ger=0407|Hun=040e|Ita=0410|Pl=0415|Por=0816|pt-BR=0416|Rus=0419|Es=040a|Swe=041d|Trk=041f
tLngName=en

[Interface.07]
Description=Netzwerk-Unterstützung (LAN/WLAN) in WindowsPE
Panel=1
pFrame1=Programmstart,707070,1:0,0,10,0,125,55
pFrame2=Programmversion,707070,1:0,0,140,0,125,55
pFrame3=Verknüpfungen + Download,707070,0,0,10,55,255,90
pFrame4=PENetwork-Konfiguration,707070,0,0,270,55,278,90
pFrame6=Verfügbare Einstellungen,707070,0,0,10,150,540,195
pFrame7=Profilpfade,707070,1,0,10,145,540,210
pFrame8=PENetwork-Profil (INI-Datei),707070,1,0,30,160,500,90
pFrame9=WLAN-Profil (XML-Datei),707070,1,0,30,250,500,90

pScrollBox1=Start von RAM,1,1:0,0,20,20,105,20,Start von RAM
pScrollBox2=5,1,1:0,0,225,231,45,20,5,10,15,20,25
pScrollBox3=Auto,1,0,0,430,117,110,20,Auto,Deutsch,Englisch,Französisch,Italienisch,Polnisch,Portugiesisch,Portugiesisch (BR),Russisch,Schwedisch,Spanisch,Tschechisch,Türkisch,Ungarisch
pScrollBox4=Hauptfenster anzeigen,1,0,0,180,301,160,20,Hauptfenster anzeigen,Programm minimieren,Programm schließen
pScrollBox5=Beta,1,1:0,0,160,20,70,20,Beta,v0.58.2

pCheckBox1=True,Startmenü,0,22,30,75,90,20
pCheckBox2=True,Desktop,0,22,30,99,90,20
pCheckBox3=False,Automatischer Download der Letztversion,0,0,30,123,230,18
pCheckBox4=True,Autostart bei WinPE-Start,0,0,30,215,190,18
pCheckBox5=True,Startverzögerung (Sek.),0,0,30,235,190,18
pCheckBox6=True,Startaufforderung als oberstes Fenster,0,0,30,255,250,18
pCheckBox7=True,Dateifreigabe nach Netzwerkstart,0,0,30,275,250,18
pCheckBox8=True,Laufwerksfreigaben nach Dateifreigabe,0,0,290,175,250,18
pCheckBox9=False,Kleine Tabs in PENetwork-GUI,0,0,290,195,250,18
pCheckBox10=True,Gerätesuche bei jeder Ausführung,0,0,290,215,250,18
pCheckBox11=True,Verbindungsaktivität im Infobereich anzeigen,0,0,290,235,250,18
pCheckBox12=True,Netzwerkdienste immer installieren,0,0,290,255,250,18
pCheckBox13=True,Debug-Modus,0,0,290,275,140,18

pTextBox1=.,Startmenü-Ordner,0,0,135,80,120,20

pTextLabel1=Verfügbare Sprachen:,9,0,Default,290,120,137,20
pTextLabel2=Nach Netzwerkstart:,9,0,Default,30,305,150,20

pButton1=PE_License,PENetwork-Lizenz,0,Button,275,10,100,30
pButton2=AutoIt3_License,AutoIt3 EULA,0,Button,380,10,90,30
pButton3=ReadMe,READ ME,0,Button,470,10,80,30
pButton4=Debug,Debug-Info,0,Button,430,274,91,20
pButton5=ProfileEditor,Profil-Editor (englisch),1,Button,400,175,120,30
pButton6=InfoINI,INI-Info,1,Button,320,185,70,20
pButton7=WLanEditor,WLAN-Editor (englisch),1,Button,400,265,120,30
pButton8=InfoWLAN,WLAN-Info,1,Button,320,275,70,20
pButton9=Open_INI,Ordner öffnen,1,Button,400,215,100,20
pButton10=Open_WLAN,Ordner öffnen,1,Button,400,305,100,20

pRadioButton1=True,Automatische Konfiguration,0,1,290,73,200,20
pRadioButton2=False,Eigene Einstellungen,0,1,290,95,200,20
pRadioButton3=True,Startaufforderung,0,2,30,175,250,20
pRadioButton4=False,Automatische IP-Konfiguration,0,2,30,195,250,20

pFileBox1=%BaseDir%\Temp\PENetwork\INI\,PENet (*.ini),1,FileDir,50,215,300,20
pFileBox2=%BaseDir%\Temp\PENetwork\WLAN\,WLan (*.xml),1,FileDir,50,305,300,20
//----Echo
tEcho_3=Download von
tEcho_4=Systemdateien werden kopiert...
tEcho_5=Das WLAN-Profil wird nach 'Windows\System32' kopiert...
tEcho_6=Download-Datei wird extrahiert...
tEcho_7=[PENetwork.ini] wird geschrieben...
tEcho_8=Registry-Dateien werden geschrieben...
tEcho_9=Editor wird ausgeführt...
tEcho_10=Die Profilauswahl wird aktiviert...
//----Information
tMsg_1=Wählen Sie bitte einen Ordner aus
tMsg_2=Es wurde keine WLAN-Konfigurationsdatei (.xml-Datei) gefunden.#$xIntegration in PENetwork ist nicht möglich.
tMsg_3=Es können nur Dateien mit Endung 'xml' integriert werden.#$xIntegration dieser Datei ist nicht möglich.#$x#$xBitte überprüfen Sie Ihre Einstellungen.
tMsg_4=Es wurde keine Datei definiert.#$xDas Skript verwendet jetzt die Einstellungen für#$x#$x- 'Automatische Konfiguration'
tMsg_5=Die gewählte Datei ist keine INI-Datei.#$xDas Skript verwendet jetzt die Einstellungen für#$x#$x- 'Automatische Konfiguration'
tMsg_6=Die gewählte Datei enthält keine verwertbaren Informationen.#$xDas Skript verwendet jetzt die Einstellungen für#$x#$x- 'Automatische Konfiguration'
tMsg_7=Die definierte INI-Datei wurde nicht gefunden.#$xDas Skript verwendet jetzt die Einstellungen für#$x#$x- 'Automatische Konfiguration'
tMsg_9=PENetwork-Profil:
tMsg_10=WLAN-Profil:
//----Fehler
tMsg_11=Fehler beim Erkennen der Sprache des Quell-Mediums.#$x#$xPENetwork verwendet daher als Installations-Sprache ENGLISCH.

tLangList_beta=|de-DE=0407|en-US=0409|fr-FR=040c|it-IT=0410|pl-PL=0415|pt-PT=0816|pt-BR=0416|ru-RU=0419|sv-SE=041d|es-ES=040a|cs-CZ=0405|tr-TR=041f|hu-HU=040e
tLangList_0582=|Ger=0407|Eng=0409|Fr=040c|Ita=0410|Pl=0415|Por=0816|pt-BR=0416|Rus=0419|Swe=041d|Es=040a|Cs=0405|Trk=041f|Hun=040e

tLngName=de


[pRadioButton1]
Update,InterfaceVar
Interface,State,,Hide,pFrame7,pFrame8,pFrame9,pButton5,pButton6,pButton7,pButton8,pButton9,pButton10,pFileBox1,pFileBox2
Interface,State,,Show,pFrame6,pRadioButton3,pRadioButton4,pScrollBox2,pScrollBox4,pCheckBox4,pCheckBox5,pCheckBox6
Interface,State,,Show,pCheckBox7,pCheckBox8,pCheckBox9,pCheckBox10,pCheckBox11,pCheckBox12,pCheckBox13,pTextLabel2,pButton4

[pRadioButton2]
Update,InterfaceVar
Interface,State,,Hide,pFrame6,pRadioButton3,pRadioButton4,pScrollBox2,pScrollBox4,pCheckBox4,pCheckBox5,pCheckBox6
Interface,State,,Hide,pCheckBox7,pCheckBox8,pCheckBox9,pCheckBox10,pCheckBox11,pCheckBox12,pCheckBox13,pTextLabel2,pButton4
Interface,State,,Show,pFrame7,pFrame8,pFrame9,pButton5,pButton6,pButton7,pButton8,pButton9,pButton10,pFileBox1,pFileBox2

[pRadioButton3]
Update,InterfaceVar
Interface,State,,Show,pCheckBox5,pCheckBox6,pScrollBox2

[pRadioButton4]
Update,InterfaceVar
Interface,State,,Hide,pCheckBox5,pCheckBox6,pScrollBox2

[Open_INI]
Update,InterfaceVar
If,Not,%pFileBox1%,=,,Then
	StrFormat,%Path%,PATH,%pFileBox1%
	If,Not,ExistDir,%Path%,Then,DirMake,%Path%
	Start,,%Path%
Else
	Message,%tMsg_1%,INFORMATION,4
End

[Open_WLAN]
Update,InterfaceVar
If,Not,%pFileBox2%,=,,Then
	StrFormat,%Path%,PATH,%pFileBox2%
	If,Not,ExistDir,%Path%,Then,DirMake,%Path%
	Start,,%Path%
Else
	Message,%tMsg_1%,INFORMATION,4
End

[PE_License]
Start,%WindowsDir%\Notepad.exe,%ScriptDir%\PENetwork_MC\License.txt,%ProjectDir%

[AutoIt3_License]
Start,%WindowsDir%\Notepad.exe,%ScriptDir%\PENetwork_MC\EULA-AutoIt3.txt,%ProjectDir%

[ReadMe]
If,Not,ExistFile,%ScriptDir%\PENetwork_MC\PENetwork_ReadMe_%tLngName%.html,Then,Set,%tLngName%,en
RegRead,%Html%,HKCR,.html,,
RegRead,%BrowserPath%,HKCR,%Html%\shell\open\command,,
Start,%BrowserPath%,%ScriptDir%\PENetwork_MC\PENetwork_ReadMe_%tLngName%.html

[Debug]
If,Not,ExistFile,%ScriptDir%\PENetwork_MC\Debug-Info_%tLngName%.html,Then,Set,%tLngName%,en
RegRead,%Html%,HKCR,.html,,
RegRead,%BrowserPath%,HKCR,%Html%\shell\open\command,,
Start,%BrowserPath%,%ScriptDir%\PENetwork_MC\Debug-Info_%tLngName%.html

[InfoWLAN]
If,Not,ExistFile,%ScriptDir%\PENetwork_MC\WLAN-Info_%tLngName%.html,Then,Set,%tLngName%,en
RegRead,%Html%,HKCR,.html,,
RegRead,%BrowserPath%,HKCR,%Html%\shell\open\command,,
Start,%BrowserPath%,%ScriptDir%\PENetwork_MC\WLAN-Info_%tLngName%.html

[InfoINI]
If,Not,ExistFile,%ScriptDir%\PENetwork_MC\INI-Info_%tLngName%.html,Then,Set,%tLngName%,en
RegRead,%Html%,HKCR,.html,,
RegRead,%BrowserPath%,HKCR,%Html%\shell\open\command,,
Start,%BrowserPath%,%ScriptDir%\PENetwork_MC\INI-Info_%tLngName%.html


[Variables]
Set,%ProgramTitle%,PENetwork
Set,%ProgramFolder%,PENetwork
Set,%ProgramEXE%,PENetwork.exe
Set,%FileStorage%,%AppsDir%\PENetwork_MC
If,%pScrollBox5%,=,Beta,Then
	Set,%UrlPath_32%,https://penetworkmanager.de/scripts/PENetwork.7z
	Set,%UrlPath_64%,https://penetworkmanager.de/scripts/PENetwork_x64.7z
Else
	Set,%UrlPath_32%,https://penetworkmanager.de/scripts/PENetwork_x86_%pScrollBox5%.7z
	Set,%UrlPath_64%,https://penetworkmanager.de/scripts/PENetwork_x64_%pScrollBox5%.7z
End
Set,%ExtractDIR%,%AppsDir%\PENetwork_MC
Set,%PENetworkINI%,%ExtractDIR%\PENetwork_%Arch%\PENetwork.ini
Set,%TopMost%,0
Set,%ShowTrayActivity%,0
Set,%StartSharing%,
Set,%ShareAll%,
Set,%ForceScanOnStartup%,0
Set,%EnableAutoIP%,0
Set,%ForceServices%,0
Set,%pRadioButton1_Var%,0
Set,%pRadioButton2_Var%,0
Set,%Autostart%,0
Set,%ProfileCountdown%,
Set,%FocusNo%,0
Set,%UseStartCountdown%,0
Set,%StartCountdown%,%pScrollBox2%
Set,%SmallTab%,0
Set,%UseProfiles%,1
Set,%UseProfileSelect%,0
Set,%UseProfileCountdown%,0
Set,%Debug%,0
Set,%EnableAutoIP%,0
Set,%ForceScanOnStartup%,0
Set,%MinimizeToTray%,0
Set,%CloseAfterStartnet%,1
Set,%Langlist%,cs=Cs=0405|en=Eng=0409|es=Es=040a|fr=FR=040c|de=Ger=0407|hu=Hun=040e|it=Ita=0410|ja=Jpn=0411|ko=Kor=0412|pl=Pl=0415|pt=Por=0816|pt=pt-BR=0416|ru=Rus=0419|sv=Swe=041d|tr=Trk=041f|zh=zh-CN=0804|zh=zh-TW=0404

[Process]

//+++++++++++++++++++++++++++++++++++++++++++++++++++
//----ÜBERPRÜFUNG AUF LSP-VERSION | CHECK LSP VERSION
//+++++++++++++++++++++++++++++++++++++++++++++++++++
If,%LSPVer%,<,1.2.3.4,Then,Message,LSPVersion,Msg||1.2.3.4

Run,%ScriptFile%,Variables
Echo,201,Txt|PENetwork

//+++++++
//----RAM
//+++++++
Interface,GetIndex,,pScrollBox1,%Idx%
String,%RunFrom%,Split,True|False,|,%Idx%
RunFromRAM,%RunFrom%

Set,%ProgDir%,%Target_prog%\%ProgramFolder%
DirMake,%ProgDir%

//++++++++++++++++++++++
//----DOWNLOAD | EXTRACT
//++++++++++++++++++++++
If,Not,ExistFile,%ExtractDIR%\PENetwork_%Arch%\PENetwork_%pScrollBox5%.exe,Then,Run,%ScriptFile%,Pre_LSP_Extract,1

//++++++++++++++++++++++++++++++++++++++++++++
//----PENETWORK-SPRACHEN | PENETWORK LANGUAGES
//++++++++++++++++++++++++++++++++++++++++++++
// Auto = Automatische Auswahl | Automatic selection
// -------------------------------------------------
Set,%NetLang%,
Interface,GetIndex,,pScrollBox3,%Idx%
If,%Idx%,=,1,Then
	// PENetwork latest Beta
	If,%pScrollBox5%,=,Beta,Then
		Run,%ScriptFile%,DistLang
	Else
	// latest PENetwork Final
		String,%Check%,Left,%DistLang%,2

		String,%count%,SPLIT,%Langlist%,|,0
		For,%x%,1,%count%
			String,%Var%,SPLIT,%Langlist%,|,%x%
			String,%Var2%,SPLIT,%Var%,=,1
			If,%Check%,=,%Var2%,Then
				String,%NetLang%,SPLIT,%Var%,=,2
				String,%LangCode%,SPLIT,%Var%,=,3
				ExitLoop
			End
		Next
	End
Else
	// Auswahl gemäß Interface | Selection according to Interface
	// ----------------------------------------------------------
	// PENetwork latest Beta
	If,%pScrollBox5%,=,Beta,Then
		Set,%Langlist%,%tLangList_Beta%
	Else
	// latest PENetwork Final
		Set,%Langlist%,%tLangList_0582%
	End
	Interface,GetIndex,,pScrollBox3,%Idx%
	String,%Var%,SPLIT,%Langlist%,|,%Idx%
	String,%NetLang%,SPLIT,%Var%,=,1
	String,%LangCode%,SPLIT,%Var%,=,2
End

// PENetwork Final 0.58.2 (--> Keine Sprachübereinstimmung mit %DistLang%)
// PENetwork Final 0.58.2 (--> languages do not correspond to %DistLang%)
If,Not,%pScrollBox5%,=,Beta,Then
	If,%NetLang%,=,,Then
		Message,%tMsg_11%,INFORMATION,6		
		Set,%NetLang%,Eng
		Set,%LangCode%,0409
	End	
End

//++++++++++
//----TARGET
//++++++++++
RegLoad,%RegSystem%,PE-SYSTEM
RegRead,%Name%,HKLM,PE-SYSTEM\ControlSet001\Control\ComputerName\ComputerName,ComputerName
RegUnLoad,PE-SYSTEM

FileCopy,%ExtractDIR%\PENetwork_%Arch%\PENetwork_%pScrollBox5%.exe,%ProgDir%\PENetwork.exe

//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
//----PROFIL - AUSWAHL "EIGENE EINSTELLUNGEN" | PROFILE - SELECTION "CUSTOM SETTINGS"
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
// --> Fehler führen grundsätzlich zur AUTOMATISCHEN KONFIGURATION
// --> Errors will always lead to AUTO CONFIGURATION

If,Not,%pRadioButton1%,=,True,Then
	Set,%AutoErr%,
	If,%pFileBox1%,=,,Then
		Set,%AutoErr%,%tMsg_4%
	Else
	// DATEIENDUNG | FILE EXTENSION
	// ----------------------------
		StrFormat,%Var%,EXT,%pFileBox1%
		If,Not,%Var%,=,.ini,Then
			Set,%AutoErr%,%tMsg_9%#$x#$x%tMsg_5%
		Else
		// DATEIPFAD + DATEINAME | FILE PATH + FILE NAME
		// ---------------------------------------------
			If,Not,ExistFile,%pFileBox1%,Then
				Set,%AutoErr%,%tMsg_7%
			Else
				// DIESE INI-SEKTIONEN SIND ZWINGEND ERFORDERLICH | THESE SECTIONS HAVE TO EXIST
				// -----------------------------------------------------------------------------
				// --> PENetwork + NetProfiles
				If,Not,ExistSection,%pFileBox1%,PENetwork,Then
					Set,%AutoErr%,%tMsg_9%
				Else
					If,Not,ExistSection,%pFileBox1%,NetProfiles,Then
						Set,%AutoErr%,%tMsg_6%
					End
				End
			End
		End
	End
	If,%AutoErr%,=,,Then				
		// EINTRÄGE UND VARIABLEN FÜR REGISTRY | SETTINGS AND VARIABLES FOR REGISTRY
		// -------------------------------------------------------------------------
		IniReadPos,%Var%,%pFileBox1%,NetProfiles,count
		IniRead,%ProfileDefault%,%pFileBox1%,PENetwork,ProfileDefault
		For,%x%,1,%Var%
			IniReadPos,%ProfileName%,%pFileBox1%,NetProfiles,KeyPos,%x%
			IniWrite,%pFileBox1%,%ProfileName%,CMDStart.CMD1,X:\Windows\System32\Peinit.exe -penstart
			IniWrite,%pFileBox1%,%ProfileName%,CMDStart.Start1,Normal
			IniWrite,%pFileBox1%,%ProfileName%,CMDStart.Wait1,Yes
		Next
		IniRead,%Computername%,%pFileBox1%,%ProfileDefault%,Computername
		If,%Computername%,=,,Then
			IniWrite,%pFileBox1%,%ProfileDefault%,Computername,%Name%
		End						
		IniRead,%StartSharing%,%pFileBox1%,%ProfileDefault%,StartSharing
		IniRead,%ShareAll%,%pFileBox1%,%ProfileDefault%,ShareAll
		// Startaufforderung | Start prompt
		// --------------------------------
		IniRead,%Var%,%pFileBox1%,PENetwork,Autostart
		If,%Var%,=,Yes,Then
			Set,%Autostart%,1
		End
		// Button-Fokus bei Startaufforderung | Button focus for Start prompt
		// ------------------------------------------------------------------
		IniRead,%Var%,%pFileBox1%,PENetwork,FocusNo
		If,%Var%,=,Yes,Then
			Set,%FocusNo%,1
		End
		// Startverzögerung | Start delay
		// ------------------------------
		IniRead,%Var%,%pFileBox1%,PENetwork,UseStartCountdown
		If,%Var%,=,Yes,Then
			Set,%UseStartCountdown%,1
		End
		// Sekundenanzeige der Startverzögerung | Seconds for Start delay
		// --------------------------------------------------------------
		IniRead,%StartCountdown%,%pFileBox1%,PENetwork,StartCountdown
		// Position des PENetwork-Fensters | Position of PENetwork windows
		// ---------------------------------------------------------------
		IniRead,%StartMode%,%pFileBox1%,PENetwork,StartMode
		// Profil / Profile
		// ----------------
		IniRead,%Var%,%pFileBox1%,PENetwork,UseProfiles
		If,%Var%,=,No,Then
			Echo,%tEcho_10%
		End
		// Profilauswahl | Profile selection
		// ---------------------------------
		IniRead,%Var%,%pFileBox1%,PENetwork,UseProfileSelect
		If,%Var%,=,Yes,Then
			Set,%UseProfileSelect%,1					
		End
		// Sekundenanzeige der Profilauswahl | Seconds for Profile selection
		// -----------------------------------------------------------------
		IniRead,%UseProfileCountdown%,%pFileBox1%,PENetwork,UseProfileCountdown
		If,%Var%,=,Yes,Then
			Set,%UseProfileCountdown%,1
			IniRead,%Var%,%pFileBox1%,PENetwork,ProfileCountdown
			Set,%ProfileCountdown%,%Var%
		End
		// Installation der Netzwerkdienste | Installation of Network services
		// -------------------------------------------------------------------
		IniRead,%Var%,%pFileBox1%,PENetwork,ForceServices
		If,%Var%,=,Yes,Then
			IniWrite,%pFileBox1%,PENetwork,ForceServices,No
		End
		// Debug.txt
		// ---------
		IniRead,%Var%,%pFileBox1%,PENetwork,Debug
		If,%Var%,=,Yes,Then
			Set,%Debug%,1
		End
		// Automatische IP-Konfiguration | Automatic IP configuration
		// ----------------------------------------------------------
		IniRead,%Var%,%pFileBox1%,PENetwork,EnableAutoIP				
		If,%Var%,=,Yes,Then
			Set,%EnableAutoIP%,1
		End
		// Netzwerkkarten-Erkennung | Detection of Network cards
		// -----------------------------------------------------
		IniRead,%Var%,%pFileBox1%,PENetwork,ForceScanOnStartup
		If,%Var%,=,Yes,Then
			Set,%ForceScanOnStartup%,1
		End
		// Verbindungsaktivität im Infobereich | Tray activity
		// ---------------------------------------------------
		IniRead,%Var%,%pFileBox1%,PENetwork,ShowTrayActivity
		If,%Var%,=,Yes,Then
			Set,%ShowTrayActivity%,1
		End
		// Anzeige der PENetwork-GUI nach Netzwerkinstallation | Show Main GUI
		// -------------------------------------------------------------------
		IniRead,%ShowMain%,%pFileBox1%,PENetwork,ShowMain
		If,%Var%,=,Yes,Then
			Set,%CloseAfterStartnet%,0
		End
		// Fensterminimierung | Minimize window
		// ------------------------------------
		IniRead,%Var%,%pFileBox1%,PENetwork,MinimizeToTray
		If,%Var%,=,Yes,Then
			Set,%MinimizeToTray%,1
		End					
		FileCopy,%pFileBox1%,%ProgDir%\PENetwork.ini	
	Else	
		Message,%AutoErr%,INFORMATION,4
		Run,%ScriptFile%,AutoConfig
	End
Else
	//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
	//----AUSWAHL "AUTOMATISCHE KONFIGURATION" | "AUTO CONFIGURATION"
	//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
	Run,%ScriptFile%,AutoConfig
End

// %Arch%
FileCopy,%ExtractDIR%\PENetwork_%Arch%\PENetwork_%NetLang%.lng,%ProgDir%
FileCopy,%ExtractDIR%\PENetwork_%Arch%\startnet.exe,%ProgDir%

//++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
//----WLAN - AUSWAHL "EIGENE EINSTELLUNGEN" | "SELECTION "CUSTOM SETTINGS"
//++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
If,%pRadioButton2%,=,True,Then
	If,ExistFile,%pFileBox2%,Then
		// ÜBERPRÜFUNG AUF DATEIENDUNG .XML | CHECKING FILEEXTENSION .XML
		StrFormat,%Var%,EXT,%pFileBox2%
		If,%Var%,=,.xml,Then
			Echo,%tEcho_5%
			FileCopy,%pFileBox2%,%target_sys%
		Else
			// FEHLERMELDUNG | ERROR MESSAGE
			Message,%tMsg_3%,INFORMATION,4
		End
	Else
		// FEHLERMELDUNG | ERROR MESSAGE
		Message,%tMsg_10%#$x#$x%tMsg_2%,INFORMATION,4
	End
End

Run,%ScriptFile%,Registry

//+++++++++++++++
//----ADDSHORTCUT
//+++++++++++++++
If,%pCheckBox1%,=,True,Then,Add_Shortcut,StartMenu,%pTextBox1%,%Pe_Programs%\%ProgramFolder%\%ProgramEXE%,%ProgramTitle%
If,%pCheckBox2%,=,True,Then,Add_Shortcut,Desktop,,%Pe_Programs%\%ProgramFolder%\%ProgramEXE%,%ProgramTitle%
If,%pCheckBox4%,=,True,Then,System,SetPEInit,A,Startup,Run||%PE_Programs%\%ProgramFolder%\%ProgramEXE%

[Pre_LSP_Extract]
If,%pCheckBox3%,=,True,Then
	FileDelete,%FileStorage%\PENetwork_x86_%pScrollBox5%.7z,1
	FileDelete,%FileStorage%\PENetwork_x64_%pScrollBox5%.7z,1
	FileDelete,%ExtractDIR%\PENetwork_x86\PENetwork_%pScrollBox5%.exe,1
	FileDelete,%ExtractDIR%\PENetwork_x64\PENetwork_%pScrollBox5%.exe,1
Else
	If,%pScrollBox5%,=,Beta,Then
		FileDelete,%FileStorage%\PENetwork_x86_v0.58.2.7z,1
		FileDelete,%FileStorage%\PENetwork_x64_v0.58.2.7z,1	
	End
	If,%pScrollBox5%,=,v0.58.2,Then
		FileDelete,%FileStorage%\PENetwork_x86_Beta.7z,1
		FileDelete,%FileStorage%\PENetwork_x64_Beta.7z,1	
	End
End
System,ProcessMode
// PENetwork 32-Bit
Run,%ScriptFile%,Download_Extract,%UrlPath_32%,x86
// PENetwork 64-Bit
Run,%ScriptFile%,Download_Extract,%UrlPath_64%,x64
// Überprüfung Ordnergröße | Check folder size
Echo,210,Txt
Wait,2000
Retrieve,%DirSize%,DirSize,%ExtractDIR%
If,Not,%DirSize%,=,%DirSize_orig%,Then
	DirRemove,%ExtractDIR%,1
	Message,Err_DirSize,Msg|
End

[Download_Extract]
If,Not,ExistDir,%FileStorage%,Then,DirMake,%FileStorage%
If,Not,Existfile,%FileStorage%\PENetwork_#2_%pScrollBox5%.7z,Then
	//----Download
	Echo,%tEcho_3% [PENetwork_#2_%pScrollBox5%]...
	WebGet,#1,%FileStorage%\PENetwork_#2_%pScrollBox5%.7z
	// Download-Fehler | Download error
	If,%Exitcode%,=,1,Then,Message,Err_Download,Msg|
	// MD5-Prüfsummenvergleich | MD5 checksum comparison
	If,%pScrollBox5%,=,Beta,Then
		Set,%DirSize_orig%,9736079
		If,#2,=,x86,Then,Set,%ServerMD5%,47afc6a0b84e2c10e6fac687f2209fc9
		If,#2,=,x64,Then,Set,%ServerMD5%,cb3997cada76c60d3bf3604e5550245b
	End
	If,%pScrollBox5%,=,v0.58.2,Then
		Set,%DirSize_orig%,4528440
		If,#2,=,x86,Then,Set,%ServerMD5%,d5336a7a436f71c5c0480014107dd723
		If,#2,=,x64,Then,Set,%ServerMD5%,03abeac64fb2198058ef0b9adcd6c14f
	End
	Retrieve,%FileMD5%,MD5,%FileStorage%\PENetwork_#2_%pScrollBox5%.7z
	If,Not,%FileMD5%,=,%ServerMD5%,Then
		Message,Err_MD5,Msg|
		FileDelete,%FileStorage%\PENetwork_#2_%pScrollBox5%.7z
		Exit		
	End
End
If,Existfile,%FileStorage%\PENetwork_#2_%pScrollBox5%.7z,Then
	//----Extract
	Echo,207,Txt
	Wait,700
	DirRemove,%ExtractDIR%\PENetwork_#2,3
	
	pack,decompress,%FileStorage%\PENetwork_#2_%pScrollBox5%.7z,%ExtractDIR%\PENetwork_#2
	FileRename,%ExtractDIR%\PENetwork_#2\PENetwork.exe,%ExtractDIR%\PENetwork_#2\PENetwork_%pScrollBox5%.exe
End

[AutoConfig]
Echo,%tEcho_7%
Wait,700
Set,%pRadioButton1%,True
IniWrite,%PENetworkINI%,Static IP address,Computername,%Name%
IniWrite,%PENetworkINI%,Dynamic IP address,Computername,%Name%

//----04.10.2014: 'PENetwork.ini v0.58.2 and higher'
IniWrite,%PENetworkINI%,PENetwork,UseProfileSelect,No
IniWrite,%PENetworkINI%,PENetwork,UseProfileCountdown,No
IniWrite,%PENetworkINI%,PENetwork,ProfileCountdown,

//----31.01.2016: 'PENetwork.ini v0.59.B3 and higher'
If,Not,%pScrollBox5%,=,v0.58.2,Then
	IniWrite,%PENetworkINI%,PENetwork,UseOSFont,Yes
	IniWrite,%PENetworkINI%,PENetwork,GlobalFont,Tahoma
	IniWrite,%PENetworkINI%,PENetwork,UseIniIcons,No
End

//----08.11.2022
IniWrite,%PENetworkINI%,Static IP address,CMDStart.CMD1,X:\Windows\System32\PEInit.exe -penstart
IniWrite,%PENetworkINI%,Static IP address,CMDStart.Start1,Normal
IniWrite,%PENetworkINI%,Static IP address,CMDStart.Wait1,Yes

IniWrite,%PENetworkINI%,Dynamic IP address,CMDStart.CMD1,X:\Windows\System32\PEInit.exe -penstart
IniWrite,%PENetworkINI%,Dynamic IP address,CMDStart.Start1,Normal
IniWrite,%PENetworkINI%,Dynamic IP address,CMDStart.Wait1,Yes

//++++++++++++++++++++++++++++++++++++++++++++++++
//----INTERFACE-EINSTELLUNGEN | INTERFACE SETTINGS
//++++++++++++++++++++++++++++++++++++++++++++++++
// Startaufforderung / Start prompt
// --------------------------------
If,%pRadioButton3%,=,True,Then
	IniWrite,%PENetworkINI%,PENetwork,AutoStart,Yes
	
	// Button-Fokus bei Startaufforderung | Button focus for Start prompt
	IniWrite,%PENetworkINI%,PENetwork,FocusNo,No
	
	// Startverzögerung + Sekundenanzeige | Start delay + seconds
	If,%pCheckBox5%,=,True,Then
		Set,%UseStartCountdown%,1
		IniWrite,%PENetworkINI%,PENetwork,UseStartCountdown,Yes
		IniWrite,%PENetworkINI%,PENetwork,StartCountdown,%StartCountdown%
	Else
		IniWrite,%PENetworkINI%,PENetwork,UseStartCountdown,No	
	End
	
	// Startaufforderung als oberstes Fenster | Start prompt as uppermost window
	If,%pCheckBox6%,=,True,Then
		Set,%TopMost%,1
		IniWrite,%PENetworkINI%,PENetwork,TopMost,Yes
	Else
		IniWrite,%PENetworkINI%,PENetwork,TopMost,No
	End
Else
	Set,%AutoStart%,1
	IniWrite,%PENetworkINI%,PENetwork,AutoStart,Yes
End

// Automatische IP-Konfiguration | Automatic IP configuration
// ----------------------------------------------------------
If,%pCheckBox8%,=,True,Then
	Set,%EnableAutoIP%,1
	IniWrite,%PENetworkINI%,PENetwork,EnableAutoIP,Yes
Else
	IniWrite,%PENetworkINI%,PENetwork,EnableAutoIP,No
End

// Position des PENetwork-Fensters | Position of PENetwork window
// --------------------------------------------------------------
Set,%StartMode%,1
IniWrite,%PENetworkINI%,PENetwork,StartMode,%StartMode%

// Kleine Tabs | Small tabs
// ------------------------
If,%pCheckBox9%,=,True,Then,Set,%SmallTab%,1
IniWrite,%PENetworkINI%,PENetwork,SmallTab,%SmallTab%

// Profilverwendung | Profile
// --------------------------
IniWrite,%PENetworkINI%,PENetwork,UseProfiles,No

// Netzwerkkarten-Erkennung | Detection of Network cards
// -----------------------------------------------------
If,%pCheckBox10%,=,True,Then
	Set,%ForceScanOnStartup%,1
	IniWrite,%PENetworkINI%,PENetwork,ForceScanOnStartup,Yes
Else
	IniWrite,%PENetworkINI%,PENetwork,ForceScanOnStartup,No
End

// Verbindungsaktivität im Infobereich | Tray activity
// ---------------------------------------------------
If,%pCheckBox11%,=,True,Then
	Set,%ShowTrayActivity%,1
	IniWrite,%PENetworkINI%,PENetwork,ShowTrayActivity,Yes
Else
	IniWrite,%PENetworkINI%,PENetwork,ShowTrayActivity,No
End

// Installation der Netzwerkdienste | Installation of Network services
// -------------------------------------------------------------------
If,%pCheckBox12%,=,True,Then,Set,%ForceServices%,1

// Debug.txt
// ---------
If,%pCheckBox13%,=,True,Then
	Set,%Debug%,1
	IniWrite,%PENetworkINI%,PENetwork,Debug,Yes
Else
	IniWrite,%PENetworkINI%,PENetwork,Debug,No
End

// Anzeige der PENetwork-GUI nach Netzwerkinstallation + Fensterminimierung | PENetwork GUI + Minimize windows
// -----------------------------------------------------------------------------------------------------------
Interface,GetIndex,,pScrollBox4,%Idx%
If,%Idx%,=,1,Then
	Set,%CloseAfterStartnet%,0
	IniWrite,%PENetworkINI%,PENetwork,ShowMain,Yes
	IniWrite,%PENetworkINI%,PENetwork,MinimizeToTray,No
Else
	Set,%MinimizeToTray%,1
	IniWrite,%PENetworkINI%,PENetwork,ShowMain,No
	IniWrite,%PENetworkINI%,PENetwork,MinimizeToTray,Yes
End

FileCopy,%PENetworkINI%,%ProgDir%

[Registry]
RegLoad,%RegSoftware%,PE-SOFTWARE
RegLoad,%RegUser%,PE-USER
// Windows XP, Win2003
If,%NTVersion%,=,5,Then
	RegWrite,HKLM,0x2,PE-SOFTWARE\Classes\CLSID\{7007ACC7-3202-11D1-AAD2-00805FC1270E}\shell\open\command,,#$q%PE_Programs%\%ProgramFolder%\%ProgramEXE%#$q
	ShellExecute,Hide,%ExtractDIR%\PENetwork_x86\PENetwork_%pScrollBox5%.exe,"/inipatch #$q%target_win%\inf#$q"
End

Echo,%tEcho_8%
RegWrite,HKLM,0x1,PE-USER\Software\PENetwork,MinimizeToTray,%MinimizeToTray%
RegWrite,HKLM,0x1,PE-USER\Software\PENetwork,ShowTrayActivity,%ShowTrayActivity%
RegWrite,HKLM,0x1,PE-USER\Software\PENetwork,SmallTab,%SmallTab%
RegWrite,HKLM,0x1,PE-USER\Software\PENetwork,StartMode,%StartMode%
RegWrite,HKLM,0x1,PE-USER\Software\PENetwork,StartToTray,1

RegWrite,HKLM,0x4,PE-SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinPE,SkipWaitForNetwork,1

RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,AutoStart,%AutoStart%
RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,CloseAfterStartnet,%CloseAfterStartnet%
RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,Debug,%Debug%
RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,EnableAutoIP,%EnableAutoIP%
RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,FocusNo,%FocusNo%
RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,ForceScanOnStartup,%ForceScanOnStartup%
RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,ForceServices,%ForceServices%
RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,LangCode,%LangCode%
RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,ShareAll,%ShareAll%
RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,ShowTrayActivity,%ShowTrayActivity%
If,%pCheckBox5%,=,True,Then
	RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,StartCountdown,%StartCountdown%
End
RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,TopMost,%TopMost%
RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,UseProfiles,%UseProfiles%
RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,ProfileCountdown,%ProfileCountdown%
RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,UseProfileSelect,%UseProfileSelect%
RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,UseProfileCountdown,%UseProfileCountdown%
RegWrite,HKLM,0x1,PE-SOFTWARE\PENetwork,UseStartCountdown,%UseStartCountdown%

RegUnLoad,All

[DistLang]
If,Not,ExistFile,%ExtractDIR%\PENetwork_%Arch%\PENetwork_%DistLang%.lng,Then
	If,Not,%DistLang%,=,fr-CA,AND,Not,%DistLang%,=,es-MX,Then
		// Hongkong-Source (bis inklusive Windows 8.1) verwendet Sprache 'Taiwanesisch'
		// Hongkong source (up to Windows 8.1) uses language 'taiwanese'
		If,%DistLang%,=,zh-HK,Then
			FileCopy,%ExtractDIR%\PENetwork_%Arch%\PENetwork_zh-TW.lng,%ProgDir%
			Set,%NetLang%,zh-TW
			Set,%LangCode%,0404
		Else
			Message,%tMsg_11%,INFORMATION,6
			FileCopy,%ExtractDIR%\PENetwork_%Arch%\PENetwork_en-US.lng,%ProgDir%
			Set,%NetLang%,en-US
			Set,%LangCode%,0409
		End
	End
	If,%DistLang%,=,fr-CA,Then
		FileCopy,%ExtractDIR%\PENetwork_%Arch%\PENetwork_fr-FR.lng,%ProgDir%
		Set,%NetLang%,fr-FR
		Set,%LangCode%,040c
	End
	If,%DistLang%,=,es-MX,Then
		FileCopy,%ExtractDIR%\PENetwork_%Arch%\PENetwork_es-ES.lng,%ProgDir%
		Set,%NetLang%,es-ES
		Set,%LangCode%,040a
	End
Else
	FileCopy,%ExtractDIR%\PENetwork_%Arch%\PENetwork_%DistLang%.lng,%ProgDir%
	RegLoad,%RegSystem%,PE-SYSTEM
	RegRead,%LangCode%,HKLM,PE-SYSTEM\ControlSet001\Control\Nls\Language,InstallLanguage
	RegUnLoad,PE-SYSTEM
	Set,%NetLang%,%DistLang%
End


[ProfileEditor]
Update,InterfaceVar

Run,%ScriptFile%,Variables
If,Not,ExistFile,%ExtractDIR%\PENetwork_%Arch%\PENetwork_%pScrollBox5%.exe,Then,Run,%ScriptFile%,Pre_LSP_Extract,1
Echo,%tEcho_9%
ShellExecute,Open,%ExtractDIR%\PENetwork_x86\PENetwork_%pScrollBox5%.exe,"/profileeditor"

[WLanEditor]
Update,InterfaceVar

Run,%ScriptFile%,Variables
If,Not,ExistFile,%ExtractDIR%\PENetwork_%Arch%\PENetwork_%pScrollBox5%.exe,Then,Run,%ScriptFile%,Pre_LSP_Extract,1
Echo,%tEcho_9%
ShellExecute,Open,%ExtractDIR%\PENetwork_x86\PENetwork_%pScrollBox5%.exe,"/wifiexporter"


[Script-Pic]
0=1410,1896,ZLB64
1=eNoBggV9+olQTkcNChoKAAAADUlIRFIAAAAwAAAAMAgGAAAAVwL5hwAAAAZiS0dEAP8A/wD/oL2nkwAAAAlwSFlzAAAASAAAAEgARslrPgAABMBJREFUaN7tmD9sW0Ucxz+OPFoZmFwRpIpnqwNCipnSIepmJ5YQS5vASLYGUrWhSwNjsRigoEZJNmdDJJFQAclpvNVZUZ0lQsa9CaM+qQOK9cZIx3B374/93vNzbGeAfKXTvXf3u7vv93e/392z4QpX+H8jNfQIuS/hwHsX87q2dX0Iq83h552kgM/k93KLt3lyeof1RgosTdo6Jm8tA1BkDosZ1jcLkK4ATVVWL+CkIZCO68zLZQmwVf8ZRJ76u3egcwTWY5d8kTmKzAHw8GAOEPxy9yPqvM+WaMLRvEQcT0xI5KR5uSzbYk+FiJVRjbVNVZdz5K1lvuW+Jg3FGah3VA1QvPkrD/kRd466Dd+1xy4idEKXPItB4kA+awHQBhamccn7Ibqq3vpdkF/7cqIi+kKoj3z9w9CBC9NB4tZ0z/M7f8HN36j7B1kZ+CIvxykiOJFEIhaDFtr7xvN+kkaAS/5vr1904muAdleAI8KZRbX70VxNTfW3HuqVHEV+7WUf8UFIQj4WSchreCHkel8LsDLQQp3vay+5S5Odg9tufItuMGn95B/c9t5Pz3x93R7brgUEdzbMrrf9+aOdEAFhKK/pkYtgXaNtK8+YcPKLASCph8eICAF6F3iqCFtZ1nfeBCyMmPq0EmNNK1/6w8Tv/UlB5YBEIvzEQZ1C6r29+QGcF0GTNuQBnv+pnkXXI396Nn7yUWEVE0KH6uxulV3igHruOZFE6WMArD9+ikzUKAKjQgkQgNgAq+JbEWjtBsn7RWjkvz5TFxVPsULID0rIUYVG7MCiCujW4AnaYlfZ669R0ZmctwPQR63KAfNJbG5foXPBnEJR6A2lhKfQyLviuydCLjIjwlFl5QdVolC/NpTjxr07SkBrF6iAKPhWyqv26n0l5Nbj/tG2gPMN1c/xQOJx5C8qzMuB1iu48alO3lceQYAXXyWarN01R6qVyD4J+UHCepLY50U74feILSCdB6vti83kAkYNKRVC93Lqq9R4Pp3rS9BYuGE0HAaRTyLOS2JbeF433IcRQSGx5aB8SERe73YghAozJZroIzWtL7UZoLMcP5ktgHibYUIlKfmggEop1TyalxgBFng5saeq841EuTFKXA87diq+e14Vqw1Wm0I6N3jGIX6MjEN4UEDpOMWLW0Clx0wLAZjZGzv5JDkRhfAf1xtHkpmSDqMNX8cxiE+gE5HchwkEXERk1JjXz1LhIVQpKWECEBX6d+SCGCd5jfi/N7ZXJFTVs4X3qdH5Jn7RsESvrgbXKmxLl5ypXwM8G+ovl2TG20i9qtcWJiIJcYP5IyXAL+ICAtKJrNz/NZuwXZDq1v0c/nkQbh9FegK4tIUA9vf3peM4OI7DvYMbhO3Ayspbnh+q1YH8ku3AiKjVatJxHHI53z1y8CbUNpvNus9LS0tSC48UMnEBjUZDGlKOM/iDzy/ALyRKxNTAGUckPzs729du23bkmEwm4xYjJpvNUi6XZZj9pYRQJpPBcRy3zmaz1B7ZwHXgOiov3nNtwdstMyYKE0/iWq3m7kIvEfNuEtv/bIpt25ycnNBoNEK5XsopZE6fhYWFUOJhAgxxx3EiyV+aAINqtSp7BRiEiYo7fa5whSv8R/AvzVpZZm3LKXUAAAAldEVYdGRhdGU6Y3JlYXRlADIwMTEtMDgtMTZUMTU6NTk6MDArMDA6MDC9pVHAAAAAJXRFWHRkYXRlOm1vZGlmeQAyMDExLTA4LTE2VDE1OjU5OjAwKzAwOjAwzPjpfAAAAABJRU5ErkJgghcHiCY=
