[Main]
Title=VirtualBox Emulation
Description=Runs your ISO in Virtual Machine
Selected=False
Level=9
Author=Kare;MaineCoon
Version=15.9
Date=05.12.2025
Disable=Virtual Test\VMware.srt,Virtual Test\BestEmu.srt

[Interface]
Panel=1
pFrame1=,707070,0,0,0,0,400,105
pframe2=Settings,707070,1:0,0,0,105,550,188
pFrame3=Finalization,707070,1:0,0,0,293,400,65

ptextlabel1=VirtualBox is an Open Source program that runs ISO files in a#$xvirtual environment.,10,0,Default,20,20,370,40
pTextLabel2=NOTE:#$xVirtualBox has to be installed on your HDD,10,0,Bold,20,60,320,40
ptextlabel3=Allocated memory (Mb):,10,0,Default,20,130,180,20
ptextlabel4=BootISO:,10,0,Default,20,165,60,20
pTextLabel5=HDD Controller,9,1:0,Default,280,211,90,20
pTextLabel6=Re-execution of scripts#$x'0-PostConfig.srt' and 1-create_iso.srt',10,1:0,Default,20,314,230,40
pTextLabel7=Bootorder:,10,1:1,Default,375,242,60,18

pCheckBox1=True,Network,0,3,10,210,65,18
pCheckBox2=True,Audio,0,3,10,240,50,18
pCheckBox3=True,Hard disk,1:0,0,200,240,68,18
pCheckBox5=False,UEFI Boot,1:0,0,200,210,80,18

pScrollBox1=3072,1,1:0,0,228,127,60,20,1024,1536,2048,2560,3072,4096
pScrollBox2=,1,0,0,110,162,310,22,
pButton2=Script-Select,,1:0,Refresh.bmp,428,161,25,25,Resfresh
pScrollBox3=Intel-Pro1000MT,1,0,0,80,209,105,20,PCnet-Fast III,Intel-Pro1000MT
pScrollBox4=HDAudio,1,0,0,80,239,105,20,ICH AC97,HDAudio
pScrollBox5=Used,1,1:0,0,280,240,70,20,New,Used,Custom
pScrollBox6=SATA,0,1:0,0,375,210,70,20,IDE,SATA
pScrollBox7=DVD,0,1:1,0,450,239,60,20,DVD,HDD

pFileBox1=,VHD (*.vhd;*.vmdk),1:1,FileDir,280,265,230,20

pButton1=all,Finalize,1:0,,325,315,60,25

pWebLabel1=https://www.virtualbox.org/wiki/Downloads,Download Page,0,Web,420,25,100,20
pTextLabel8=USB,9,1:0,Default,25,272,40,18
pScrollBox8=USB 1.1,0,1:0,0,80,269,105,20,USB 1.1,USB 2.0,USB 3.1


//
tEcho_1=Processing 'VirtualBox'...
tEcho_2=Starting Virtual Machine ( %DispName% )...

tMsg_1=VirtualBox is not installed on this PC#$x#$xAborting script...
tMsg_2=No ISO file found
tMsg_3=No VMHDD file found
tMsg_4=VirtualBox is already running
tMsg_5=Script setting for VBox memory:#$x- %pScrollBox1% Mb#$x%VOS% needs at least:#$x- %RamNeed% MB.#$x#$xDo you want to aply this setting %RamNeed% Mb ?
tMsg_7=System not recognized, choose Windows version
tmsg_8=Not enough memory#$x#$xneeds at least: %RamNeed%#$xAvailable memory: %FreeRam%
tMsg_9=No UEFI support for %OS% or architecture %ArchIso%.#$x#$xSupported Operating Systems:#$x- Windows 8/8.1, Windows 10#$x#$xArchitecture:#$x- x64
tMsg_13=USB 2/3 need Extension Pack. Install it first.

tHalt_1=VirtualBox needs at least %RamNeed% Mb. Aborting script...
tQuestion=SELECTION

[Interface.07]
Panel=1
Description=Startet die erstellte ISO-Datei in einer Virtuellen Maschine
pframe1=,707070,0,0,0,0,400,105
pframe2=Einstellungen,707070,1:0,0,0,105,550,188
pframe3=Finalisierung,707070,1:0,0,0,293,400,65
ptextlabel1=VirtualBox ist eine Open-Source-Software#$c die ISO-Dateien in#$xvirtuellen Umgebungen ausführt.,10,0,Default,20,20,370,40
ptextlabel2=WICHTIG:#$xVirtualBox muss auf Ihrem PC installiert sein,10,0,Bold,20,60,320,40
ptextlabel3=Zugewiesener Speicher (MB):,10,0,Default,20,130,180,20
ptextlabel4=ISO-Datei:,10,0,Default,20,165,80,20
ptextlabel5=HDD-Controller,9,1:0,Default,280,211,90,18
ptextlabel6=Erneute Ausführung der Skripte#$x'0-PostConfig.srt' und 1-create_iso.srt',10,1:0,Default,20,314,230,40
pTextLabel7=Bootorder:,9,1:1,Default,375,242,65,18

pcheckbox1=True,Netzwerk,0,3,10,210,65,18
pcheckbox2=True,Audio,0,3,10,240,50,18
pcheckbox3=True,Festplatte,1:0,0,200,240,68,18
pCheckBox5=False,UEFI Boot,1:0,0,200,210,75,18

pscrollbox1=3072,1,1:0,0,228,127,60,20,1024,1536,2048,2560,3072,4096
pScrollBox2=,1,0,0,110,162,310,22,
pButton2=Script-Select,,1:0,Refresh.bmp,428,161,25,25,Aktualisieren
pscrollbox3=Intel-Pro1000MT,1,0,0,80,209,105,20,PCnet-Fast III,Intel-Pro1000MT
pscrollbox4=HDAudio,1,0,0,80,239,105,20,ICH AC97,HDAudio
pscrollbox5=Benutzt,1,1:0,0,280,240,70,20,Neu,Benutzt,Eigene
pscrollbox6=SATA,0,1:0,0,375,209,70,20,IDE,SATA
pScrollBox7=DVD,0,1:1,0,455,240,60,20,DVD,HDD
pfilebox1=,VHD (*.vhd;*.vmdk),1:1,FileDir,280,265,230,20
pbutton1=all,Finalisieren,1:0,,310,315,80,25
pweblabel1=https://www.virtualbox.org/wiki/Downloads,Download Seite,0,Web,420,25,120,20
pTextLabel8=USB,9,1:0,Default,25,272,40,18
pScrollBox8=USB 1.1,0,1:0,0,80,269,105,20,USB 1.1,USB 2.0,USB 3.1

techo_1='VirtualBox' wird ausgeführt.
techo_2=VirtualBox wird gestartet ( %DispName% )...
tmsg_1=VirtualBox ist auf diesem Computer nicht installiert.#$x#$xSkript wird abgebrochen.
tmsg_2=Keine übereinstimmende ISO-Datei gefunden
tmsg_3=VMHDD-Datei wurde nicht gefunden
tMsg_4=VirtualBox wird bereits ausgeführt
tmsg_5=Skript-Einstellung für den VBox-Speicher:#$x- %pScrollBox1% MB#$x%VOS% benötigt mindestens:#$x- %RamNeed% MB.#$x#$xWollen Sie die Einstellung auf %RamNeed% MB übernehmen ?
tmsg_7=System nicht erkannt, wähle Windowsversion
tmsg_8=Arbeitsspeicher zu wenig#$x#$x%VOS% benötigt mindestens: %RamNeed%#$xVerfügbarer Speicher: %FreeRam%
tMsg_9=Keine UEFI-Unterstützung für %OS% oder Architektur %ArchIso%.#$x#$xUnterstützte Betriebssysteme:#$x- Windows 8/8.1, Windows 10#$x#$xArchitektur:#$x- x64
tMsg_13=USB 2/3 benötigt das Extension Pack. Installiere es zuerst.

thalt_1=VirtualBox benötigt mindestens %RamNeed% MB. Skript wird abgebrochen...
tquestion=AUSWAHL


[Script-Select]
Search,%AllIsos%,File,%IsoDir%,*.iso
Interface,Set,,pScrollBox2,%IsoFileName%,%AllIsos%

[pScrollBox5]

Update,InterfaceVar
Interface,GetIndex,,pScrollBox5,%HDDSt%
Set,%Var%,Hide
If,%HDDSt%,=,3,Then,Set,%Var%,Show
Interface,State,,%Var%,pFileBox1,pTextLabel7,pScrollBox7


[Process]

Echo,%tEcho_1%
//----ÜBERPRÜFUNG AUF INSTALLIERTE VERSION
//++++++++++++++++++++++++++++++++++++++++
Set,%VBPath%,

RegRead,%VBPath%,HKLM,SOFTWARE\InnoTek\VirtualBox,InstallDir
If,%VBPath%,=,,Then,RegRead,%VBPath%,HKLM,SOFTWARE\Sun\xVM VirtualBox,InstallDir

If,%VBPath%,=,,Then
	System,REGREDIRECT,64
	RegRead,%VBPath%,HKLM,SOFTWARE\Sun\xVM VirtualBox,InstallDir
	System,REGREDIRECT,OFF
End
If,%VBPath%,=,,Then
	System,REGREDIRECT,64
	RegRead,%VBPath%,HKLM,SOFTWARE\Sun\VirtualBox,InstallDir
	System,REGREDIRECT,OFF
End
If,%VBPath%,=,,Then
	System,REGREDIRECT,64
	//	RegRead,%VBPath%,HKLM,SOFTWARE\Oracle\VirtualBox,InstallDir,%VBPath%
	RegRead,%VBPath%,HKLM,SOFTWARE\Oracle\VirtualBox,InstallDir
	System,REGREDIRECT,OFF
End
Set,%VBoxManage%,%VBPath%VBoxManage.exe

If,Not,ExistFile,%VBoxManage%,Then
	Message,%tMsg_1%,ERROR,6
	Exit
End

If,ExeRunning,VirtualBox.exe,Then,Message,%tMsg_4%,Exit

Set,%AskOS%,0
Set,%Bootorder%,0
Set,%ExtPack%,0
If,ExistFile,%VBPath%\ExtensionPacks\Oracle_VM_VirtualBox_Extension_Pack\ExtPack.xml",then,Set,%ExtPack%,1

//----AUSWAHL DER ISO-DATEI
//+++++++++++++++++++++++++
If,%BuildMode%,<,2,Then
	Search,%AllIsos%,File,%IsoDir%,*.iso
	Interface,Set,,pScrollBox2,%IsoFileName%,%AllIsos%
	Set,%ArchIso%,%arch%
Else
	// %OS% und %Arch% aus dem Namen der ISO-Datei auslesen
	// 16.09.2019
	If,%pscrollbox2%,=,,Then,Message,%tMsg_2%,Exit
	Set,%ISOfile%,%ISODir%\%pscrollbox2%
	StrFormat,%DispName%,FILENAMEEX,%pScrollBox2%
	String,%ArchIso%,RIGHT,%DispName%,3
	String,%Pos%,FIND,%pScrollBox2%,[
	// LSP-MergePE
	If,%Pos%,>,9,Then,String,%Pos%,FIND,%pScrollBox2%,_

	Math,%Pos%,%Pos%-1
	// %OS% der ISO-Datei
	String,%OS%,LEFT,%pScrollBox2%,%Pos%
	If,%OS%,=,,Then,Set,%AskOS%,1

	Set,%IsoFile%,%IsoDir%\%pScrollBox2%
End
If,Not,ExistFile,%IsoFile%,Then,Message,%IsoFileName%:#$x%tMsg_2%,Exit


//----Erstellung von VirtualBox
//+++++++++++++++++++++++++++++
StrFormat,%FileName%,FILENAME,%IsoFile%
StrFormat,%DispName%,FILENAMEEX,%FileName%

StrFormat,%ISOFileShortPath%,SHORTPATH,%ISOfile%

// Closemedium - verhindert Mehrfachausführung ein- und derselben .iso-Datei + Abmeldung der .iso-Datei
// ----------------------------------------------------------------------------------------------------
iniread,%var%,%BaseDir%\Temp\VMHDD\Settings.ini,Main,HddController
if,not,%var%,=,,then
//	Message,test
//String,%Name%,Split,%var%,|,1
//Start,Hide,%VBoxManage%,startvm %Name%
//exit
	IniDeleteSection,%BaseDir%\Temp\VMHDD\Settings.ini,Main,HddController
	String,%Name%,Split,%var%,|,1
	String,%HDDCtl%,Split,%var%,|,2
	String,%Port%,Split,%var%,|,3

	ShellExecute,Hide,%VBoxManage%,storageattach %Name% --storagectl #$q%HDDCtl%#$q --%port% --device 0 --type hdd --medium #$qnone#$q
end

ShellExecute,Hide,%VBoxManage%,unregistervm %DispName% --delete

ShellExecute,Hide,%VBoxManage%,closemedium dvd #$q%ISOfile%#$q
ShellExecute,Hide,%VBoxManage%,closemedium dvd #$q%ISOFileShortPath%#$q

DirRemove,%UserProfile%\.VirtualBox\Machines\%DispName%,3
DirRemove,%UserProfile%\VirtualBox VMs\%DispName%,3


// Anmeldung der .iso-Datei
// ------------------------
ShellExecute,Hide,%VBoxManage%,createvm --name %DispName% --register

// IDE
ShellExecute,Hide,%VBoxManage%,storagectl %DispName% --name #$qIDE Controller#$q --add ide --controller PIIX4

// ISO
ShellExecute,Hide,%VBoxManage%,storageattach %DispName% --storagectl #$qIDE Controller#$q --port 0 --device 0 --type dvddrive --medium #$q%ISOFileShortPath%#$q

// Net
If,%pCheckBox1%,=,True,then
	Interface,GetIndex,,pScrollBox3,%Var%
	// PCnet-Fast III
	If,%Var%,=,1,Then,Set,%nictype%,Am79C973
	// Intel-Pro1000MT
	If,%Var%,=,2,Then,Set,%nictype%,82540EM
	ShellExecute,Hide,%VBoxManage%,modifyvm %DispName% --nictype1 %nictype% --cableconnected1 on
	ShellExecute,Hide,%VBoxManage%,modifyvm %DispName% --nic1 nat
Else
	ShellExecute,Hide,%VBoxManage%,modifyvm %DispName% --nic1 none
End

// Sound
If,%pCheckBox2%,=,True,then
	Interface,GetIndex,,pScrollBox4,%Var%
	ShellExecute,Hide,%VBoxManage%,modifyvm %DispName% --audio dsound --audioout on
	// ICH AC97
	If,%Var%,=,1,Then,ShellExecute,Hide,%VBoxManage%,modifyvm %DispName% --audiocontroller ac97
	// HDAudio
	If,%Var%,=,2,Then,ShellExecute,Hide,%VBoxManage%,modifyvm %DispName% --audiocontroller hda
Else
	ShellExecute,Hide,%VBoxManage%,modifyvm %DispName% --audio none
End

// USB
Interface,GetIndex,,pScrollBox8,%Var%
If,%ExtPack%,=,0,and,%Var%,>,1,then
  message,%tMsg_13%,Information|VB USB
  Set,%Var%,1
End
If,%Var%,=,1,Then,ShellExecute,Hide,%VBoxManage%,"modifyvm %DispName% --usb on"
If,%Var%,=,2,Then,ShellExecute,Hide,%VBoxManage%,"modifyvm %DispName% --usb on --usbehci on"
If,%Var%,=,3,Then,ShellExecute,Hide,%VBoxManage%,"modifyvm %DispName% --usb on --usbehci on --usbxhci on""

// HDD
If,%pCheckBox3%,=,True,Then
	Set,%VMDDPath%,%BaseDir%\Temp\VMHDD\lsp.vmdk
	Interface,GetIndex,,pScrollBox5,%HDDSt%
	If,%HDDSt%,=,1,Then,FileCopy,%BaseDir%\Temp\VMHDD\HDD.vmdk,%BaseDir%\Temp\VMHDD\lsp.vmdk
	If,Not,ExistFile,%BaseDir%\Temp\VMHDD\lsp.vmdk,Then,FileCopy,%BaseDir%\Temp\VMHDD\HDD.vmdk,%BaseDir%\Temp\VMHDD\lsp.vmdk
	If,%HDDSt%,=,3,Then
		Set,%VMDDPath%,%pFileBox1%
		Interface,GetIndex,,pScrollBox7,%BOIdx%
		if,%BOIdx%,=,2,then
			Set,%AskOS%,1
			Set,%Bootorder%,1
		End
	End

	If,ExistFile,%VMDDPath%,Then
		Interface,GetIndex,,pScrollBox6,%HDDcn%
		If,%HDDcn%,=,1,Then
			// IDE
			ShellExecute,Hide,%VBoxManage%,storageattach %DispName% --storagectl #$qIDE Controller#$q --port 1 --device 0 --type hdd --medium #$q%VMDDPath%#$q
			iniwrite,%BaseDir%\Temp\VMHDD\Settings.ini,Main,HddController,%DispName%|IDE Controller|port 1
		End
		If,%HDDcn%,=,2,Then
			// SATA
			ShellExecute,Hide,%VBoxManage%,storagectl %DispName% --name "SATA Controller" --add sata --controller IntelAHCI
			ShellExecute,Hide,%VBoxManage%,storageattach %DispName% --storagectl "SATA Controller" --port 0 --device 0 --type hdd --medium #$q%VMDDPath%#$q
			iniwrite,%BaseDir%\Temp\VMHDD\Settings.ini,Main,HddController,%DispName%|SATA Controller|port 0
		End
	Else
		Message,%VMDDPath% %tMsg_3%,VHD
	End
End

// Betriebssysteme
// ---------------
if,%AskOS%,=,1,then
	Set,%osLst%,Win10|x64#$xWin10|x86#$xWin8|x64#$xWin8|x86#$xWin7|x64#$xWin7|x86#$xWinXP|x64#$xWinXP|x86
	message,Windows 10 64Bit#$xWindows 10 32Bit#$xWindows 8 64Bit#$xWindows 8 32Bit#$xWindows 7 64Bit#$xWindows 7 32Bit#$xWindows XP 64Bit#$xWindows XP 32Bit,Listbox|%tmsg_7%
	if,%exitcode%,=,0,then,Halt,Windowsversion abort by User
	String,%Item%,Split,%osLst%,#$x,%exitcode%
	String,%os%,Split,%Item%,|,1
	String,%ArchIso%,Split,%Item%,|,2
	Set,%VMRam%,0
end

Set,%VOS%,%os%
Set,%VMOS%,Windows10
If,%OS%,=,WinXP,Then,Set,%VMOS%,WindowsXP
If,%OS%,=,Win2003,Then,Set,%VMOS%,Windows2003
If,%OS%,=,WinVista,Then,Set,%VMOS%,WindowsVista
If,%OS%,=,Win7,	Then,Set,%VMOS%,Windows7
If,%OS%,=,Win8,	Then,Set,%VMOS%,Windows8
If,%OS%,=,Win81,Then,Set,%VMOS%,Windows81
If,%OS%,=,Win10,Then,Set,%VMOS%,Windows10
if,%ArchIso%,=,x64,then,Set,%VMOS%,%VMOS%_64

ShellExecute,Hide,%VBoxManage%,modifyvm %DispName% --ostype %VMOS%

//Bootorder
if,%Bootorder%,=,0,then
	ShellExecute,Hide,%VBoxManage%,modifyvm %DispName% --boot1 dvd --boot2 disk --boot3 none --boot4 none
Else
	ShellExecute,Hide,%VBoxManage%,modifyvm %DispName% --boot1 disk --boot2 dvd --boot3 none --boot4 none
End

// UEFI Boot
If,%pCheckBox5%,=,True,Then
	If,%ArchIso%,=,x64,and,%WIM_BUILD%,>,9000,Then
		ShellExecute,Hide,%VBoxManage%,modifyvm %DispName% --firmware efi
	Else
		Message,%tMsg_9%,INFORMATION
	end
end


//----SPEICHERBEDARF
//++++++++++++++++++
Set,%RamNeed%,1536
Set,%RamList%,WinXP=512|Win2003=256|WinVista=768|Win7=768|Win8=1024|Win81=1024|Win10=1536

String,%cnt%,SPLIT,%RamList%,|,0
For,%x%,1,%cnt%
	String,%tmp%,SPLIT,%RamList%,|,%x%
	String,%OS_Lst%,SPLIT,%tmp%,=,1
	If,%OS%,=,%OS_Lst%,then
		String,%RamNeed%,SPLIT,%tmp%,=,2
		ExitLoop
	End
Next
Math,%RamNeed%,%RamNeed%+256+%VMRam%

For,%x%,1,5
	System,FreeRam,%FreeRam%
	math,%FreeRam%,(%FreeRam%/1048576),Round_Down
	math,%DifRam%,%FreeRam%-%RamNeed%
	if,%DifRam%,>,5,then,exitloop
	wait,200
next
if,%DifRam%,<,-260,then,message,%tmsg_8%,Confirmation

Set,%tmp%,%pScrollBox1%
If,%pScrollBox1%,<,%RamNeed%,Then
    Set,%val%,
    Interface,Get,,pScrollBox1,%Var%,all
    String,%Cnt%,Split,%Var%,#$x,0
    For,%x%,1,%Cnt%
	String,%Val%,Split,%Var%,#$x,%x%
	if,%val%,>,%RamNeed%,then,Exitloop
    Next
    if,%val%,=,,then,Set,%val%,4096
    set,%pScrollBox1%,%Val%
    Interface,Set,,pScrollBox1,%Val%

// Message,%tQuestion%:#$x#$x%tMsg_5%,Question
 //   If,%ExitCode%,=,No,Then,Halt,#$s%tHalt_1%
//	Set,%pScrollBox1%,%RamNeed%
End
ShellExecute,Hide,%VBoxManage%,modifyvm %DispName% --memory %pScrollBox1%

// Boot-Verzögerung  efilogodisplaytime
ShellExecute,Hide,%VBoxManage%,modifyvm %DispName% --bioslogodisplaytime 3000
If,Not,%ExitCode%,=,0,Then,Halt,Error VirtualBox.

Echo,%tEcho_2%
Start,Hide,%VBoxManage%,startvm %DispName%
Wait,2000

[all]
Update,InterfaceVar
System,GetLangTxt,181,%Txt%
System,ProcessMode,%Txt%

if,ExistFile,%ProjectDir%\Finish\0-PostConfig.srt,Then
	System,SwitchScript,%ProjectDir%\Finish\0-PostConfig.srt
	Run,%ProjectDir%\Finish\0-PostConfig.srt,Process
	System,SwitchScript,Back
End

System,SwitchScript,%ProjectDir%\Finish\1-create_iso.srt
Run,%ProjectDir%\Finish\1-create_iso.srt,Process
System,SwitchScript,Back

Set,%BuildMode%,0
Run,%ScriptFile%,Process


[Script-Pic]
0=4731,6116,ZLB64
1=eNqllWk4FAzXx0e2KIrsNSgkyZ4liRsh3IwlI+skiTHG2NfBjShL3NbJFMpYsk40yNiyZ48py0yGIXuYsY5tPO7net/ny/vlvd73f76cc/0/nN+5znWdczJxMgO4aGJobAhgOo3HpwE4YQDE/jTQvS/+0M3VwxvhhXCHuvmLG3u7youDleQVlQAnJIA+4Mz/U6dd7nAiPVz8nroifEKRyopKygqKSgqKt8UVNTRVFDVV73A+dPMPkLPQ57xvADb4E2Qhp2igrKtheBtw0slUAAAwsTL9W4D/EtMZZhZWNvazHJznmADMTP+t/2FeBJxhYmY+w8LMysrCcupEnHoAFh5W3qtKumyXLF3Yr/nyKUenvT8roVfdxm81QpVUeeIXw8EpICgkLCJ1XfqGzM3bqmrqGnc09e8bGBo9MDaxfmgDtn1kZ+/61O2ZuwfU0z8gMCg4JDQs9nlc/IuXCYnpGZlZ2ajXOegCTGFRccmH0rKaT7jauvrPDfj2js6u7p6vvX2jhO8/xsYnJomU2blf8wuLS8srtM2t7Z3dPfr+Ac8p8hkWFmYW9n+Qmc4E/zMPDwvrVSU2Xl1LdhffS9eUo8/y6aW9r27jkFCxovI/8RvhFJC8TZGi/UP9b+j/HXPM/wn6P8z/QT75AuA5C9AEaDAzndLzAJh5ACdEwHlmptPiNNcBHO+Qyxp+XSg5k9lMMpALk2sF/EpGtl740jZ2BHrvISBoX1VZardMjHjO5RsaHu7Ln5tbwWm4XOW9LnI35Jp1h1bNtfh942H+EaNz4IrM0NAIm2bkwKI9HybqK929B1IXl8vILx+mOnSMa2sScJ8Vin9oizsmNbNT4lP53z1ya8zohEMDy+g5ct7SySDETO5lu4gJY/lrxPl7K8L3ZT7gsaicNsk9b5C3zVMsGWTmUJuz+LCqbEq2hI/koApjaEaMrYei2k4ApJQNcIr+7GW4SledgIHBCeAlQ8Ah5IUV46teygKI90iZxgfOv7j9Rp+/eWDEU1NS9AYupJJMWYyTPLx9L6Si4FW+QuMPLxQ5g+R0VFVrtmnVacLdi5VajsCHetd+O1z9EiWE5Jo7FuEKbmeIj9YO3vTWweGSviIqn/wtvwX3n1fKHlo2ugAL5FPnnJY1FEukls/zi+9jLp8AggZ1nHswIOFg9/VauPCKz099TfbokW+0zKsv2NlZAttmDmljTZPtRere4IrRYDAUOOIDy0EcHAjYfJ8TzbniutqzVagyiEU6eOLnGbFRElAs4DnJKWI12A5jK+oz4J0s/Ben7VMME0San2CSvI/RMCJKlZv0QuptTgDcrrcXCzKSfkc+jPwGYWcoetSTr9PUu95MGc3uxUnl3d1gPdLHjbjRbOO1+WXkGcGJ2kzQUd0SzzTDNHxr8rvUrtkhsl3T4Bk7ew1vRgbXq3YdV9azI7vQbotgc/jk9aKiytoKfLPm/udEfoxAAanVCV3Tkg3asg2TX51LgvCsnADOz2hr0YJQ/jRQJ0OuPuoC3X32V8vVfFu6//uQUAqa47eWOJqfnBGpWt54Lukldtuh0uELviiusAZqAdVEqodljjMGSjsuC5Wp2pztIe9CpWSM780fkzZo/s4r4E+oVM4sn3RPiwWrkfrAp+QyMggxsD0tsiowzaMtQLdm8O21J91RfeDeOLq95m6I/mpMXZn+03FFVG68Ytu3MATWJqpC+9RzvQiKXVkVHwng0nTSG++cT7+znRJmni1QHi/LY/3GqF+oQc8KKpnhDbZ0mDRC22+W312VWWp+e2kHBwlewR1O4VEtF+mmsyWv7LdD2K0zunX4kIcOcKM5yPP1qiZZigLzcXZE+mQIqudj+y2GFtnBaEH6SGKxA390sblcHzG7yLkh8LpULz3OpIxvudeYUBLpmSVRmX99O2s+vLcYZ5UcZG+diWGr7MfmZo1Oqpa8AUHSDoAVSK86usq75RYgTTr5Kj2aZkhsl40wQ9514U5D+If5X3PyrPtm5u9W0JZgpR4jjWbMxwyhkT77NfqDRrLYHEK5poa3iWLsm1LbqRrjqfblBlWE1IJJF94/tbUsHYfA/PBYq2W4/3S+0pR3AjAYxa7rJWwErJqW2hgC0kOswMzLjcBPyX+rJNLx37NECIW53y/b1tZFpBY/x5qoyj07CGrYDz8BsArQEEktV+zo+l1kzjEsUqfMYI7ruoTqp3d1DTFzHeRrXNAoqMIB/3xhjzknlWwkeefyx7NfDyJFi8wIAU8JGSPwkn3RZ+4J2ZyjxiT8pBDkU+oRH7v+2K+P1Pwum0/UqJdST2tjdsGZdH2HtERJGHB+JBvCPTVAypFTvWMQneEFPoh2BTZrjYuXxvthTdaM1b7b7EfAq4XOjwqlBhUV1DmOQQJPAPpLwy/za4ZjtMWB
2=1l3THDt3FeLzlMd/x67WgQ/M8j5R52ZZlGVy1iLFQzjXJL4h9RFh6V8FH1anEKyq0SunY9Y69Ut0KLyKH3B/jn4V0j/Zbd/grBLTXLg8bIhryUX0bcO1B8C8uTZhcsaF058J9b1OlfAJqpPCrisV1THMFQVnECLlqKnxyEvwIIQX4zxSNvYhdSO6Sf8DsbEfuJfIOji496pF0rPmgtz2sTJjHQYXUfPAcLBnIFx/9wjailla9/lslbKl7+68D9VTXh0YjVNQ3yXam4xo9ZjkisCHfJNRkwuWWb83nlY27xrbH65PJx3Bj+swdaOtFA46pFiXuteuBsa6FkPxcs2VqJeIW39eF3+56+ClJf14BDAi9bY89Mb+E7RdZpfY98ch/lwxz31fE9db7thbFMyHych5bddnV8p/pUm/vjvEs4HQUd/a3M8XQwJpAo1ziARP1Ho/lDvXN2r3Adkw2STw3LlA9IKxcfrK8vPfztBPEgL+3Wbhyp3gLsqqTLeQB6FInV9vDCqXL/cj3ylVHY3ptAryNS8MgFZ9YGQdXSrt8S+Y0PvMRh4iil442kq4yES/0X1PlvbTC55cXoQJL6kZt93PL7QCtxM2a+qPmGdAdJmLTjqU7txZXTg8CHlvFsS60k5eF7oe4+WJT3kl6Y1S/En6awRmjhmqwz8XYDN1KGQjQyAvUIdP7Kv6rWPVUrW5euUE6uqXt3QkVU8AzB556iNvOk8v22M8XiDbkyFFfTURYxZl1JB4Hb1qg8MlikP+yPWHszbJatqRDYAV3IPBwFcvps2LipdaY4qw87CNFeSru5EbmJhsov3BSoTMIdORD/2NG831D7pO+Oy5XFCbZlZ80wgU3VSzoi5yBW+YFhrFvIQa9vO+vVScd0Hmd5Hy8qxWL4wLV2HHiErcTL6t6FNqUN43uDnpSWwh5o2ZvSoH8WhCAzwZZUQs/bKQTl1rItJSrBshRGor9RS0Np0NGAn4XIxeoOH6bUYrWESCkphVpNCDfr8Pn6S6mor7cg7YG+7V3Az42HRPoOHJ/pNtY4jpCaAj77r7mvTrWndMjZP2xqbWxsz4l8tJveM9JwBBjBkzZSEHxt0QrNYYuSso8lPZFHFNL/0WbdB761ZiZH+wau7gtjKI/+2Fm8CWSBUxK58S85iF1FsNlTXQE0BO7XmtqzImWPzsaGIdnmG6czhsSVVI0hYNwc6Cq32pw+0wSj5HiGwb5s/a4Dj4+k5jrr4dygYFbo312uwKGPSEY8JX+5v1YCEuaei+C/ICG/1OD2aqtZa7t296N5ZERNxyty90luASUohvkh9LHE/JPpwanrwQc9C4IuJW+Abf3Sr/ew72OFLjeqvGAEP9dLcROxcoRcv7jl+Pi5EXKGJiIU/pDj1/P0AqVBqxFu4l+OzGDDGIDKCR2WfBl3/g8ogMMhkGfhPAa84rkzUbZJ3nlJTHXVN6tqtxTbZo81rlDXAHXqalt1y6rnX8SIluTcPs+tMzDu+sMncS3QbHWmfcgg4Vkr3gWa4ESmPOOzOJrjqe5q5aLBGzWSndkCY1qvWH8wPXFJlnpiKHyWoupvwct/Qfehr3ZGQET5UzjHqf+PXRPdNCQvoCKqUte2GiJIeIYfBxepMBBXSRMZrPuSMn3eG7JCqZLZZgRa8yDe8trP6xHgjkZRwATch3/2p1SauS37D9XWABd0kkE5kDhbfihY9lvn0pLUt/Cw/Zutfo1VoIy7B5Me7Gzx9uV25PhJXMRciTvp0+eI9pgSVtwHHhkdHsMI/HNKkOH9QwG3qbxIRAaG/wGrxbtqZ7+o0r9WVX65Y56MlXdVo1qWF9+IXucm60y0Q9fizT7VjW9KTEO+HDNMoGodDqlLzFmQldsMJZe5tM3VqvQjZi6aRZ1Bpwlqm4C3+Pe2zz7svtr7+yxzvwrI1lk6SpFb9r3QhVlo/J9qQh6r1fNNMgPBIMrg++Zp7cKhcvRtTbLBUNIOStrKzJJw1Nmd9ygsAQ7uu4So+d/RMAJHoNzZ06k/pcYLEN73ZEXOxU4NOHcxfdNjH7GdQrruQ4ZV842lGwbFJvK/YkujB9fdf2GRu1cE8x7DU6U5Hu+e1VRkBxI0LwvdAtYOiPEhlItqqE/BQiaisyd3hS5y+Rh2POQELTD1+J+8Kvk6ME/xT1n66MNM3p9YcSQE2Hfea9Bl6tlNRgGuSF15ERZmpZ/Zvk7rgiToG5rKb+tdLeI/6DxXmJqy2O4ygO1du/RwmQVesHbdb291qMFsN/0vMpkOTa4RdkScIz2ng7qZJN9jBCc2XA034sttA4aNeW2sX6NQ2p+65dqibeSWQtbjC3KS/w7fiN/iJss9DWyO734uZi0bESwQ2T4+z17oDyLvNHYX/jPI+LK7KysKV9R3ePM5FXKYgU
3=MjedQo11qEEwrdF4V1qEt37lAZWdTI2+r7mgOvYcktMcdINv9kRQSFQpAgcPcSAhV/tu97MdXw3pF1hhK1+wSbB9VW+l2pG5o7Yl6FxSbpiVlVXjHtxj6h4wFwXKz9kaX9OldjAE2LtBPBHF21Cief5s4+Gaaa/j1JTerprl2bWngUq6W1dDn+UP3e+emMkIZV5X7swzyuo3f3TD37QwEjit/0vFRJkxkoVtBUFQi6UzjJu0wZIY5GXscj7HrbV3sR3Zy4jg2QdXTXNvdli0NCQO3cAtO5oKvlRdTXqRVfhdXjJ9lBjgw7vd7VK/vQqaNNn+QZEsLBKLW24eQ7NyKpAMVANJsLC80kMgkvsH0rIsVXh1NTg8OFyHhFU9t6EGK29MED4Huk1AhV6JxrlNsBKT4jjZB569/kCEEbvlh81hYnaG2kNKliWwSY9K76T15YnjSWp8PNo8n0VGyCLtnRWbEu7xL+5kkHYtVQid4jcNkqh7a780MmGSrEuic2dFV1PELjXxRIWHF4b06xMKvqsOc8v9VIamA5KqloK/vQyUA74ttUFbVDtOakVjTPs9zsGFXUixFR8a5LDuI56NkS2Gqi5B+fDUTIXaCJV2kcGexBahkPQOw8/qMgrJ2oIhBUajeQu6ndPQ6nx1Tef3HANB+OM4XDbqOTyTTKqw7FntjrvlJabaUDF6hJ2POKpy2UnEEZMv1SXkn0f60wZfpGq5Yh09W24QkNKUXJNNh1yjP74p2HY6S48520RL41oy7qfc/1jrHodxCJX+lGjxZdrxrIhp4EGFyCNkjZAOnG+mEkaiTlDLKWW23X0mCuFYhWVgfgf2L/RGz2ukKmWQuV09ko2u+95TLWysqBSmNsvl3oUC/9XlcrEeNOXwqHN0OGhJEp8C3rQw1WCb8ZndiiojxJ0d2o1tRhOskfLczmO2Dqbz9WmHHNRDinP0DPDasOko3JUDxivud/bnnLC4n97OTXVeDX7aowGv1Yc7Qa3YnYkDVlCWgRdqeV8UeyXSvuwDp+DHIdm/a+wBWB0m37afmBQN6bTteyuY8W8gRM5m65owJZ9rRRPYtfCessZ9sEnuc2WdWs9wCfRn2rr4THixPtRVQ9JN2JwDC5H3HrYtIHxNkAosmK7eFGuDsIVoL3bmwXvitFS16vYscbxm76F+vcwcnz1y1+wwLhPvre+XPbQp2hhEQqBVecUPrQ46cQ67Ota4fhjM9Aaltj6GKDRnkabL59MdW8UvYWMj/BuAlelzJDSG7yAGRtHOxDC5wRDGUoU0TQHyfam0JLvl+c5TsZPJfwHKkFOp

[Refresh.bmp]
0=1550,1180,ZLB64
1=eNpz8uVjYwADMyDWAGIxKGZkkACL32BlwAD/cYDfQPj/DxD9/f/vN0jgHy6VOMz49euXZYql/4Yoz1UhvovCPQrccBuBacavr9+sqixcNsS6rYz2WBbpujjMZX6w05wA+1nedo3OYJfhN+P3799SPjxhW7N81kW5r4oBmuG5MNRtXpDrLH/nGb7Okzzs+1z+//+CZhKSGV+/fxd0YxBw5eFzYvNbm+SyPNJjbpDnDD+3qd7u03wcpno5TnCz7XEyrzU/e2MHsjFIZgDD7tXvD0LuHNzu3OK+XBLpcmJRjDJxPDKxfFIRXMIhHE59bg5dTnbt9radTv9/4wmP4qYSATfWmVt6f/z4AbTr4afrMlE8XP480mE8UkHc9l0ONq229o1WRiW63//8whkv//5/A5LfIS6DREfj5BrJEBbxQC5xfw7HZhugGZbVJl/+fcIbt5hA1IpH3JdH1JtLOV7SvtbcqsLIIdOMRDOA7pMJ5JPwYBPwZLWpMrEsN7Qp0SXZjP9FvaliHhxAM6wrjS3KDKyL1ZDN+AdCT7/c33lz16//v/7/+f3/Jyg0gGH6F8mMH/9/i7jxCHtxW5cbmhfrmhSqo7pDzIpPzJvHZV6S25wwq1m+jrM97Oe4G+ZoIBsCNEPUnZfPlc2qzMCsSMe4QA3VDGE3DiE3Np8FEa5zA11m+jlO85aLU0bzy/3P10QgfinSNcvVMMtSQTHjn7gbh6AHp+u8CJc5Aa7TfVymeavFa4AzLQJIOQgIu/Haluhb5emZZWkZZathmCHkyeU0O9Rxpq/bDF/HyR6OvW4uLc7/wQnyL8gjb0Xd2U3L9YGOsMzVNc3U3HRqDZIZv///EXDj4vNgd54ZyOHL4joFlDUcu53tgCm7xday1dy0ytC6RhcYpUBHWObrmWdrW2YqoqZ1YDSIOgny+XLI+ohIBfJIh/I59rnYdDvZttsDU6Vdg6VNnTnQALtSA6tCHbNcPZMMjR/o+QXoDlF7js8/3n/4+UY2nFM8jE8uQtC20cqmzc6hyRpoBjBlAxMm0BEW+VrOpfqg+Ecqk2Dx8u8fVOzX/x+igcwSkVxAJBXFp5enZFNpblVual6qb5Sp8vDn7T+//xJXFgJdFl8VLBzGKhnDLR3LndIV9Rdq8Z+/GKUivrQOytsg9A+5sMBangIAeInrwg==
